Skip to content
 

Installation silencieuse de Clavier+

Avertissement

Cet article détaille la procédure d’installation silencieuse de Clavier + destinée à s’inscrire dans le processus décrit ici, lequel vise à automatiser le déploiement d’un ensemble d’applications sur une machine tournant sous Windows.

Il n’en reste pas moins que cette procédure peut parfaitement s’appliquer de manière autonome.

Introduction

Je sais pas vous, mais moi et mes petits doigts boudinés, on adore les raccourcis clavier. Même que si j’étais un jeune trader branché qui connait la vie, le monde et le prix de toute chose, je dirais que ça impacte grave en positif la productivité.
Mais comme je suis plutôt du genre vieux con anarcho-décroissant, j’vais plus simplement dire que ça évite de se fatiguer le poignet en une série proprement minante de clics divers et variés (et quand on connait l’implication essentielle du poignet dans la cogitation informatique, on veille à l’économiser!).

Bon, on dirait par exemple que vous avez décidé de vous débarrasser une bonne fois pour toute d’un soft auquel vous ne trouvez définitivement plus aucun intérêt.
D’un mouvement vif et pourtant non dépourvu de cette subtile élégance qui fait votre charme et construit votre renommée, vous ramenez le curseur de votre souris jusqu’aux abords du bouton Démarrer pour faire apparaître le menu du même nom, vous remontez un chouïa pour aller cliquer là où que c’est marqué Panneau de configuration, où c’est-y déjà, ah oui, là! et, forcément, quand vous vous retrouvez face à l’interminable liste des rubriques, vous galérez une bonne seconde et demie pour y trouver celle que vous recherchez, à savoir la fameuse entrée Programmes et fonctionnalités qui va vous permettre de procéder enfin à l’éradication du parasite.

Ben moi, je me contente tout bêtement de faire Crtl + Win + Espace. Wouah! Trop la classe! Faut bien dire qu’on passe sa vie à désinstaller des programmes!

Voui, bon, d’accord, z’êtes pas franchement convaincus mais je vois bien aussi que vous ne faites aucun effort.

Ça va pas m’empêcher de continuer d’autant que mon petit doigt tout aussi boudiné mais autrement plus bavard que ses frangins me murmure que y’en a quand même dans le tas que la chose intéresse. Si! Si! Là bas, dans le fond, à coté du radiateur que c’est la meilleure place.

Or donc, et rien que pour ceusses du fond : En des temps anciens, j’avais coutume d’utiliser WinKey qui permettait de construire des raccourcis incluant la touche Windows et puis, un beau jour, je suis tombé sur Clavier+ qui fait la même chose et plus encore et, là, ça a été le coup de foudre. Depuis, on ne se quitte plus.
Trêve de romance, passons aux choses sérieuses…

Cahier des charges

Une des actions récurrentes de sapiens sapiens quand il sue sang et eau devant un ordinateur est d’ouvrir des dossiers, lesquels se trouvent être souvent les mêmes. Il devient évident que lui offrir des raccourcis clavier qui lui permettent d’accéder à ses répertoires favoris est le moindre des services qu’on puisse lui rendre.
Ainsi donc, voici la liste des raccourcis dédiés à l’exploration que je propose :

  • Ordinateur : Crtl + ²
  • Racine du disque C : Crtl + &
  • Racine du disque D : Crtl + é
  • Racine du disque E : Crtl + "
  • Racine du disque F : Crtl + ‘
  • Dossier Mes documents : Alt + &
  • Dossier Mes images : Alt + é
  • Dossier Ma musique : Alt + "
  • Dossier Mes vidéos : Alt + ‘
  • Dossier Program Files : Win + Q
  • Dossier temporaire C:\Windows\Temp : Win + Crtl + Q
  • Dossier du Menu Démarrer de l’utilisateur : Alt + <
  • Dossier du Menu Démarrer commun à tous les utilisateurs : Win + <

Quelques autres dédiés à des fonctions utiles :

  • Ouvrir le Panneau de configuration : Win + Alt + Espace
  • Ouvrir la fenêtre des Programmes et fonctionnalités : Crtl + Win + Espace
  • Ouvrir la fenêtre de la Gestion de l’ordinateur : Win + ²
  • Ouvrir la fenêtre du Gestionnaire de périphériques : Alt + ²
  • Ouvrir la fenêtre du Gestionnaire des tâches : MAJ + ²
  • Lancer l’Éditeur de registre : Win + w
  • Lancer CCleaner : Alt + w
  • Lancer la Calculatrice : Win + x

Et enfin, quelques raccourcis à même de faciliter l’écriture :

  • Écrire la majuscule À : Alt + MAJ + à
  • Écrire la ligature æ : Alt + a
  • Écrire la ligature majuscule Æ : Alt + MAJ + a
  • Écrire la majuscule Ç : Alt + MAJ + ç
  • Écrire la majuscule É : Alt + MAJ + é
  • Écrire la majuscule È : Alt + MAJ + è
  • Écrire la ligature œ : Alt + o
  • Écrire la ligature majuscule Œ : Alt + MAJ + o

Bon, ce sont mes raccourcis à moi et bien évidemment vous en faites ce que vous voulez… Reste qu’ils vont constituer notre base de travail.

Mise en œuvre

Clavier+ stocke l’ensemble des raccourcis qu’il a la délicate mission de gérer dans le fichier Clavier.ini, lequel se niche aux cotés de l’exécutable Clavier.exe, par défaut dans le dossier C:\Users\Nom_Utilisateur\AppData\Local\Clavier+.

On suppute qu’en forçant le remplacement du fichier Clavier.ini générique par celui qu’on a pris bien soin de mitonner aux petits oignons, on va pouvoir disposer de nos raccourcis persos comme de rien. Sauf que Clavier.ini est lu au lancement de Clavier+ et réécrit à sa fermeture. Tout changement apporté à la main pendant que le programme tourne demeure sans effet. Si l’on veut pouvoir le modifier à sa guise, il faut donc songer tout d’abord à arrêter Clavier+.

Par ailleurs, si l’on souhaite disposer de raccourcis ciblant les dossiers de l’utilisateur, il est indispensable de savoir où ils se trouvent, information qui varie en fonction de chaque machine.

Voilà donc qui définit les différentes étapes auxquelles devra se conformer notre futur script :

  • Installation silencieuse de Clavier+ 32 ou 64 bits en fonction du système sur lequel on fait mumuse.
  • Arrêt de Clavier.exe.
  • Remplacement de Clavier.ini.
  • Récupérations des chemins des dossiers Mes documents, Mes images, Ma musique, Mes vidéos de l’utilisateur.
  • Écriture des raccourcis correspondants dans Clavier.ini.
  • Lancement de l’exécutable Clavier.exe.

On commence donc logiquement par récupérer ici les installateurs qu’on veille à nommer ClavierSetup32.exe et ClavierSetup64.exe.
Le paramètre d’installation silencieuse est /VerySilent. Du fait de mon indécrottable psychorigidité, je modifie néanmoins le répertoire d’installation dont on a vu qu’il était par défaut C:\Users\Nom_Utilisateur\AppData\Local\Clavier+ pour le passer au traditionnel C:\Program Files\Clavier+. Le paramètre s’allonge donc un tantinet pour devenir /VerySilent /DIR=C:\Program Files\Clavier+.

Par ailleurs, si on jette un œil sur la structure de Clavier.ini, on trouve pour le raccourci Alt + & chargé d’ouvrir le dossier Mes documents un truc qui ressemble à ça :

<code>Raccourci=Alt + &</code>
Code=305
Commande="D:\Mes Fichiers\Laurent\Documents"
Fenêtre=Normale
GérerFichierOuvrir=1
Description=Ouvrir Mes documents

 
Je ne suis pas franchement devin mais je dirais comme ça que la deuxième ligne Code=305 renseigne la combinaison de touches Alt + &. Tentons une petite expérience qui ne mange pas de pain : on quitte Clavier+, on ouvre Clavier.ini et on y supprime cette foutue ligne; on enregistre et on relance Clavier+. Et là, ô surprise, la ligne supprimée est réapparue. En clair et pour faire court, notre script n’aura pas à se soucier d’écrire cette ligne et au final devrait avoir quelques similitudes avec ça  :

Cliquez pour afficher/cacher le code»

Conclusion et téléchargement

Dans un même dossier Clavier+, on glisse le fichier Install.vbs dans lequel on a pris soin de coller le code ci-dessus, les deux installateurs ClavierSetup32.exe et ClavierSetup64.exe, Clavier.ini qui renferme nos raccourcis préférés à l’exception de ceux qui pointent vers les dossiers Mes documents & Co de l’utilisateur puisqu’Install.vbs se charge de les écrire pour nous, et, pour finir ,un ch’ti fichier Description.txt dont le contenu vaut :

Installation de Clavier+ 10.6.2.

 
Ceux qui sont tentés par la chose peuvent la télécharger ici.
 
 

Set objShell = CreateObject("Wscript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")

'Récupération du chemin du dossier contenant le script en cours
strCheminDossierScript = objFSO.GetParentFolderName(Wscript.ScriptFullName)

'Récupération du chemin de l'installateur en fonction du système
Set WshSysEnv = objShell.Environment("SYSTEM")
If WshSysEnv("PROCESSOR_ARCHITECTURE") = "AMD64" Then
	strCheminFichierInstall = strCheminDossierScript & "\ClavierSetup64.exe"
Else
	strCheminFichierInstall = strCheminDossierScript & "\ClavierSetup32.exe"
End If

'Installation silencieuse de Clavier+
objShell.Run Chr(34) & strCheminFichierInstall & Chr(34) & " /VerySilent /DIR=""C:\Program Files\Clavier+""", 0, True

'Arret de Clavier+
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set colProcessList = objWMIService.ExecQuery("Select * from Win32_Process Where Name = 'Clavier.exe'")
For Each objProcess in colProcessList
	objProcess.Terminate()
Next

'Récupération du chemin du dossier de Clavier+ dans Program Files
strCheminDossierClavier = objShell.ExpandEnvironmentStrings("%ProgramFiles%") & "\Clavier+\" 

'Chemin de Clavier.ini
strCheminClavierIni = strCheminDossierClavier & "Clavier.ini"

'Remplacement de Clavier.ini
objFSO.CopyFile strCheminDossierScript & "\Clavier.ini", strCheminDossierClavier

'Récupération du chemin de "Mes documents" de l'utilisateur déclaré
Const MY_DOCUMENTS = &H5&
Set appShell = CreateObject("Shell.Application")
Set objFolder = appShell.Namespace(MY_DOCUMENTS)
strCheminDocuments = objFolder.Self.Path

'Récupération du chemin de "Mes images" de l'utilisateur déclaré
Const MY_PICTURES = &H27&
Set objFolder = appShell.Namespace(MY_PICTURES)
strCheminImages = objFolder.Self.Path

'Récupération du chemin de "Ma musique" de l'utilisateur déclaré
Const MY_MUSIC = &Hd&
Set objFolder = appShell.Namespace(MY_MUSIC)
strCheminMusique = objFolder.Self.Path

'Récupération du chemin de "Mes vidéos" de l'utilisateur déclaré
Const MY_VIDEOS = &He&
Set objFolder = appShell.Namespace(MY_VIDEOS)
strCheminVideos = objFolder.Self.Path


'Modification du fichier Clavier.ini en fonction du nom de l'utilisateur déclaré
strTexte = "Raccourci=Alt + &" _
& VbCrLf & _
"Commande=" & """" & strCheminDocuments & """"_
& VbCrLf & _
"Fenêtre=Normale" _
& VbCrLf & _
"Description=Ouvrir Mes documents" _
& VbCrLf & _
"GérerFichierOuvrir=1" _
& VbCrLf & _
"-" _
& VbCrLf & _
"Raccourci=Alt +é" _
& VbCrLf & _
"Commande=" & """" & strCheminImages & """"_
& VbCrLf & _
"Fenêtre=Normale" _
& VbCrLf & _
"Description=Ouvrir Mes images" _
& VbCrLf & _
"GérerFichierOuvrir=1" _
& VbCrLf & _
"-" _
& VbCrLf & _
"Raccourci=Alt + """ _
& VbCrLf & _
"Commande=" & """" & strCheminMusique & """"_
& VbCrLf & _
"Fenêtre=Normale" _
& VbCrLf & _
"Description=Ouvrir Ma Musique" _
& VbCrLf & _
"GérerFichierOuvrir=1" _
& VbCrLf & _
"-" _
& VbCrLf & _
"Raccourci=Alt + '" _
& VbCrLf & _
"Commande=" & """" & strCheminVideos & """"_
& VbCrLf & _
"Fenêtre=Normale" _
& VbCrLf & _
"Description=Ouvrir Mes vidéos" _
& VbCrLf & _
"GérerFichierOuvrir=1" _
& VbCrLf & _
"-"

'Si on est en 64 bits, rajout d'un raccourci vers Program Files(x86)
If WshSysEnv("PROCESSOR_ARCHITECTURE") = "AMD64" Then
	strTexte = strTexte & VbCrLf & _
	"Raccourci=Win + Alt + Q" _
	& VbCrLf & _
	"Commande=" & """" & objShell.ExpandEnvironmentStrings("%ProgramFiles(x86)%") & """"_
	& VbCrLf & _
	"Fenêtre=Normale" _
	& VbCrLf & _
	"Description=Ouvrir Program Files (x86)" _
	& VbCrLf & _
	"GérerFichierOuvrir=1" _
	& VbCrLf & _
	"-"
End If

Set objTextFile = objFSO.OpenTextFile(strCheminClavierIni, 8, True)
objTextFile.WriteLine(strTexte)
objTextFile.Close

'Lancement de Clavier.exe
strCheminClavierExe = strCheminDossierClavier & "Clavier.exe"
objShell.Run Chr(34) & strCheminClavierExe & Chr(34), 0, False

WScript.Quit

Powered by Hackadelic Sliding Notes 1.6.5
Page vue 5 708 fois

Laissez une réponse